#include <YSI_Coding\y_hooks>

static g_Hour;
static g_Minute;
static g_Weather;

static bool:g_TimeUpdating;
static bool:g_WeatherUpdating;

hook OnGameModeInit()
{
	g_TimeUpdating = true;
	g_WeatherUpdating = true;

	gettime(g_Hour, g_Minute);
	g_Weather = ReturnWeather(g_Hour);
}

hook OnPlayerPassedBanCheck(playerid)
{
	SetPlayerTime(playerid, g_Hour, g_Minute);
	SetPlayerWeather(playerid, g_Weather);
}

task OnTimeUpdate[60000]()
{
	if(g_TimeUpdating == true) gettime(g_Hour, g_Minute);
	if(g_WeatherUpdating == true) g_Weather = ReturnWeather(g_Hour);

	foreach(new i : Player)
	{
		SetPlayerTime(i, g_Hour, g_Minute);
		SetPlayerWeather(i, g_Weather);
	}
}

stock Time_StopUpdate(hour, minute = 0)
{
	g_TimeUpdating = false;

	g_Hour = hour;
	g_Minute = minute;

	foreach(new i : Player) SetPlayerTime(i, g_Hour, g_Minute);
}

stock Time_StartUpdate()
{
	g_TimeUpdating = true;

	gettime(g_Hour, g_Minute);

	foreach(new i : Player) SetPlayerTime(i, g_Hour, g_Minute);
}

stock Weather_StopUpdate(weather)
{
	g_WeatherUpdating = false;

	g_Weather = weather;

	foreach(new i : Player) SetPlayerWeather(i, g_Weather);
}

stock Weather_StartUpdate()
{
	g_WeatherUpdating = true;

	g_Weather = ReturnWeather(g_Hour);

	foreach(new i : Player) SetPlayerWeather(i, g_Weather);
}

stock ReturnWeather(hour)
{
	switch(hour)
	{
		case 7..19: return 2;
		case 20..23: return 0;
		case 0..5: return 1;
		case 6: return 5;
	}
	return 0;
}