#include <YSI_Coding\y_hooks>

static Level[MAX_PLAYERS];
static Experience[MAX_PLAYERS];
static HoursPlayed[MAX_PLAYERS];
static MinutesPlayed[MAX_PLAYERS];

static Timer:PlayTimer[MAX_PLAYERS];

timer TimePlaying[60000](playerid)
{
	MinutesPlayed[playerid] ++;

	if(MinutesPlayed[playerid] >= 60)
	{
		new paycheck;

		SendClientMessage(playerid, 0xeeeeeeff, "-------------------------------------------------------------------------------------");

		if(Player_GetJob(playerid) == JOB_NONE)
		{
			paycheck = 1000 + random(500);
			va_SendClientMessage(playerid, 0xeeeeeeff, "> Your {009900}$%s {eeeeee}paycheck was added to your bank account.", MoneyFormat(paycheck));
		}
		else
		{
			paycheck = 200 + random(100);
			va_SendClientMessage(playerid, 0xeeeeeeff, "> Your {009900}$%s {eeeeee}social welfare payment was added to your bank account.", MoneyFormat(paycheck));
		}
		va_SendClientMessage(playerid, 0xeeeeeeff, "> {ff5050}$%s {eeeeee}has been deducted from your bank account for billboard fees.", MoneyFormat(paycheck / 10));
		SendClientMessage(playerid, 0xeeeeeeff, "-------------------------------------------------------------------------------------");

		GameTextForPlayer(playerid, va_return("~y~Payday~n~~w~Paycheck~n~~g~$%s", MoneyFormat(paycheck)), 3000, 1);

		MinutesPlayed[playerid] = 0;
		HoursPlayed[playerid] ++;
		Experience[playerid] ++;

		if(Experience[playerid] >= Level[playerid] * 4 + 2)
		{
			Experience[playerid] = 0;
			Level[playerid] ++;

			SetPlayerScore(playerid, Level[playerid]);
			va_SendClientMessage(playerid, 0xffff00ff, "> You leveled up to level %d.", Level[playerid]);
		}
		new query[128];
		mysql_format(MySQL_GetHandle(), query, sizeof(query), "UPDATE characters SET level = %d, hours_played = %d, experience = %d WHERE id = %d", Level[playerid], HoursPlayed[playerid], Experience[playerid], Character_GetSQLID(playerid));
		mysql_tquery(MySQL_GetHandle(), query);
	}
}

hook OnPlayerConnect(playerid)
{
	Level[playerid] = 0;
	Experience[playerid] = 0;
	HoursPlayed[playerid] = 0;
	MinutesPlayed[playerid] = 0;
}

hook OnPlayerFirstSpawn(playerid)
{
	PlayTimer[playerid] = repeat TimePlaying(playerid);
}

public OnPlayerDisconnect(playerid, reason)
{
	if(Timer_IsRunning(PlayTimer[playerid]))
	{
		stop PlayTimer[playerid];
	}
	return 1;
}

stock Player_GetLevel(playerid)
{
	return Level[playerid];
}

stock Player_SetLevel(playerid, level)
{
	Level[playerid] = level;
	SetPlayerScore(playerid, level);
}

stock Player_GetExperience(playerid)
{
	return Experience[playerid];
}

stock Player_SetExperience(playerid, experience)
{
	Experience[playerid] = experience;
}

stock Player_GetHoursPlayed(playerid)
{
	return HoursPlayed[playerid];
}

stock Player_SetHoursPlayed(playerid, hours)
{
	HoursPlayed[playerid] = hours;
}

stock Player_GetMinutesPlayed(playerid)
{
	return MinutesPlayed[playerid];
}

stock Player_SetMinutesPlayed(playerid, minutes)
{
	MinutesPlayed[playerid] = minutes;
}