lcrp-samp/gamemodes/modules/player/saving/money.inc

#include <YSI_Coding\y_hooks>

static Cash[MAX_PLAYERS];

hook OnPlayerConnect(playerid)
{
	Cash[playerid] = 0;
}

stock Player_GetCash(playerid)
{
	return Cash[playerid];
}

stock Player_GiveCash(playerid, money, bool:save)
{
	GivePlayerMoney(playerid, money);

	if(money < 0) Cash[playerid] -= money * -1;
	else Cash[playerid] += money;

	if(save)
	{
		new query[84];
		mysql_format(MySQL_GetHandle(), query, sizeof(query), "UPDATE characters SET cash = %d WHERE id = %d", Cash[playerid], Character_GetSQLID(playerid));
		mysql_tquery(MySQL_GetHandle(), query);
	}
}

CMD:pay(playerid, params[])
{
	new targetid, value;
	if(sscanf(params, "ui", targetid, value)) return SendSyntaxMessage(playerid, "/pay (playerid) (amount)");

	if(value < 1) return SendErrorMessage(playerid, "Invalid amount.");
	if(playerid == targetid) return SendErrorMessage(playerid, "You can't do that.");

	if(!IsPlayerConnected(targetid)) return SendErrorMessage(playerid, "You specified an invalid player.");
	if(Player_GetCash(playerid) < value) return SendErrorMessage(playerid, "You don't have that amount of money.");
	if(!IsPlayerNearPlayer(playerid, targetid, 1.5)) return SendErrorMessage(playerid, "You aren't near that player.");

	Player_GiveCash(targetid, value, true);
	Player_GiveCash(playerid, -value, true);

	new string[86];
	format(string, sizeof(string), "* %s takes out some cash and hands it to %s.", ReturnPlayerRPName(playerid), ReturnPlayerRPName(targetid));
	ProxDetector(20.0, playerid, string, 0xD0AEEBFF, 0xD0AEEBFF, 0xD0AEEBFF, 0xD0AEEBFF, 0xD0AEEBFF);

	va_SendClientMessage(targetid, 0x009933FF, "> You have recieved $%s from %s.", MoneyFormat(value), ReturnPlayerRPName(playerid));
	va_SendClientMessage(playerid, 0x009933FF, "> You gave $%s to %s.", MoneyFormat(value), ReturnPlayerRPName(playerid));
	return 1;
}