lcrp-samp/gamemodes/modules/vehicle/ownership.inc

#include <YSI_Coding\y_hooks>

#define MAX_OWNED_VEHICLES 3

new Iterator:OwnedVehicle[MAX_PLAYERS]<MAX_VEHICLES>;

hook OnGameModeInit()
{
	Iter_Init(OwnedVehicle);
}

hook OnPlayerDisconnect(playerid, reason)
{
	Iter_Clear(OwnedVehicle[playerid]);
}

hook OnPlayerFirstSpawn(playerid)
{
	inline const OnOwnedVehicleFound()
	{
		new rows = cache_num_rows();

		for(new i; i < rows; i++)
		{
			new id = INVALID_ITERATOR_SLOT;

			cache_get_value_name_int(i, "id", id);

			Iter_Add(OwnedVehicle[playerid], id);
		}
	}
	MySQL_TQueryInline(MySQL_GetHandle(), using inline OnOwnedVehicleFound, "SELECT id FROM vehicles WHERE owner_id = %d LIMIT %d", Character_GetSQLID(playerid), MAX_OWNED_VEHICLES);
}

hook OnVehicleDeleted(sqlid)
{
	foreach(new i : Player)
	{
		if(Iter_Contains(OwnedVehicle[i], sqlid))
		{
			Iter_Remove(OwnedVehicle[i], sqlid);
			SendAdminWarningF(i, "Vehicle SQL ID %d has been deleted from the server.", sqlid);
		}
	}
}

stock bool:IsPlayerOwningVehicle(playerid, vehiclesqlid)
{
	if(Iter_Contains(OwnedVehicle[playerid], vehiclesqlid))
	{
		return true;
	}
	return false;
}

// TODO: Dealership system